Rewrite whole project as a Arduino IDE project

The lua flashing never really worked and I had so many problems flashing the hardware. The Arduino IDE does it much better so this is now written in thes Arduino language which looks like C++. Still need to explain the hardware setup.
2018-02-14 19:57:31 +01:00 · 2018-02-14 19:57:31 +01:00 · b61dddea01
commit b61dddea01
parent 4dc9e79f28
11 changed files with 162 additions and 242 deletions
--- a/esptmp.ino
+++ b/esptmp.ino
@ -0,0 +1,148 @@
+  /*
+  ESP8266 mDNS responder sample
+
+  This is an example of an HTTP server that is accessible
+  via http://esp8266.local URL thanks to mDNS responder.
+
+  Instructions:
+  - Update WiFi SSID and password as necessary.
+  - Flash the sketch to the ESP8266 board
+  - Install host software:
+    - For Linux, install Avahi (http://avahi.org/).
+    - For Windows, install Bonjour (http://www.apple.com/support/bonjour/).
+    - For Mac OSX and iOS support is built in through Bonjour already.
+  - Point your browser to http://esp8266.local, you should see a response.
+
+*/
+
+
+#include <ESP8266WiFi.h>
+#include <ESP8266mDNS.h>
+#include <WiFiClient.h>
+#include <OneWire.h>
+#include <DallasTemperature.h>
+
+const char* ssid = "Jeenas";
+const char* password = "mypass";
+
+// Data wire is conntec to the Arduino digital pin 5
+#define ONE_WIRE_BUS 5
+// Setup a oneWire instance to communicate with any OneWire devices
+OneWire oneWire(ONE_WIRE_BUS);
+// Pass our oneWire reference to Dallas Temperature sensor
+DallasTemperature sensors(&oneWire);
+
+// TCP server at port 80 will respond to HTTP requests
+WiFiServer server(80);
+
+String getTemp()
+{
+  // Call sensors.requestTemperatures() to issue a global temperature and Requests to all devices on the bus
+  sensors.requestTemperatures();
+  // Why "byIndex"? You can have more than one IC on the same bus. 0 refers to the first IC on the wire
+  return String(sensors.getTempCByIndex(0));
+}
+
+void setup(void)
+{
+  Serial.begin(115200);
+
+  // Connect to WiFi network
+  WiFi.begin(ssid, password);
+  Serial.println("");
+
+  // Wait for connection
+  while (WiFi.status() != WL_CONNECTED) {
+    delay(500);
+    Serial.print(".");
+  }
+  Serial.println("");
+  Serial.print("Connected to ");
+  Serial.println(ssid);
+  Serial.print("IP address: ");
+  Serial.println(WiFi.localIP());
+
+  // Set up mDNS responder:
+  // - first argument is the domain name, in this example
+  //   the fully-qualified domain name is "esp8266.local"
+  // - second argument is the IP address to advertise
+  //   we send our IP address on the WiFi network
+  if (!MDNS.begin("esp8266")) {
+    Serial.println("Error setting up MDNS responder!");
+    while (1) {
+      delay(1000);
+    }
+  }
+  Serial.println("mDNS responder started");
+
+  // Start TCP (HTTP) server
+  server.begin();
+  Serial.println("TCP server started");
+
+  // Add service to MDNS-SD
+  MDNS.addService("http", "tcp", 80);
+
+  // Start up the library
+  sensors.begin();
+}
+
+void loop(void)
+{
+  // Check if a client has connected
+  WiFiClient client = server.available();
+  if (!client) {
+    return;
+  }
+  
+  Serial.println("");
+  Serial.println("New client");
+
+  // Wait for data from client to become available
+  while (client.connected() && !client.available()) {
+    delay(1);
+  }
+
+  // Read the first line of HTTP request
+  String req = client.readStringUntil('\r');
+
+  // First line of HTTP request looks like "GET /path HTTP/1.1"
+  // Retrieve the "/path" part by finding the spaces
+  int addr_start = req.indexOf(' ');
+  int addr_end = req.indexOf(' ', addr_start + 1);
+  if (addr_start == -1 || addr_end == -1) {
+    Serial.print("Invalid request: ");
+    Serial.println(req);
+    return;
+  }
+  req = req.substring(addr_start + 1, addr_end);
+  Serial.print("Request: ");
+  Serial.println(req);
+  client.flush();
+
+  String s;
+  if (req == "/")
+  {
+    IPAddress ip = WiFi.localIP();
+    String ipStr = String(ip[0]) + '.' + String(ip[1]) + '.' + String(ip[2]) + '.' + String(ip[3]);
+    s = "HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n\r\n<!DOCTYPE HTML>\r\n<html>Hello from ESP8266 at ";
+    s += ipStr;
+    s += "  </html>\r\n\r\n";
+    Serial.println("Sending 200");
+  }
+  else if (req == "/tmp")
+  {
+    s = getTemp();
+    s = "HTTP/1.1 200 OK\r\nContent-Type: text/plain\r\n\r\n";
+    s += getTemp();
+    Serial.println("Sending 200");
+  }
+  else
+  {
+    s = "HTTP/1.1 404 Not Found\r\n\r\n";
+    Serial.println("Sending 404");
+  }
+  client.print(s);
+
+  Serial.println("Done with client");
+}
+