Various bugfixes, support for filtering episode lists

2014-03-15 15:44:00 +01:00 · 2014-03-15 15:44:00 +01:00 · 0da88e3577
commit 0da88e3577
parent 431ca519d3
17 changed files with 421 additions and 45 deletions
--- a/touch/SelectionDialog.qml
+++ b/touch/SelectionDialog.qml
@ -0,0 +1,84 @@
+
+/**
+ *
+ * gPodder QML UI Reference Implementation
+ * Copyright (c) 2014, Thomas Perl <m@thp.io>
+ *
+ * Permission to use, copy, modify, and/or distribute this software for any
+ * purpose with or without fee is hereby granted, provided that the above
+ * copyright notice and this permission notice appear in all copies.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES WITH
+ * REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
+ * AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY SPECIAL, DIRECT,
+ * INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM
+ * LOSS OF USE, DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR
+ * OTHER TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
+ * PERFORMANCE OF THIS SOFTWARE.
+ *
+ */
+
+import QtQuick 2.0
+
+import 'common/constants.js' as Constants
+import 'icons/icons.js' as Icons
+
+Dialog {
+    id: selectionDialog
+
+    property string title: 'Dialog'
+    property var callback: undefined
+    property var items: ([])
+    property var selectedIndex: -1
+
+    contentHeight: selectionDialogFlickable.contentHeight
+
+    Flickable {
+        id: selectionDialogFlickable
+
+        anchors.fill: parent
+        contentHeight: contentColumn.height
+
+        Column {
+            id: contentColumn
+            width: parent.width
+
+            SlidePageHeader {
+                id: header
+                color: Constants.colors.highlight
+                title: selectionDialog.title
+            }
+
+            Repeater {
+                model: selectionDialog.items
+
+                delegate: ButtonArea {
+                    width: parent.width
+                    height: 60 * pgst.scalef
+
+                    transparent: (index != selectionDialog.selectedIndex)
+
+                    PLabel {
+                        anchors {
+                            left: parent.left
+                            verticalCenter: parent.verticalCenter
+                            margins: 20 * pgst.scalef
+                        }
+
+                        text: modelData
+                        color: (index == selectionDialog.selectedIndex) ? Constants.colors.highlight : Constants.colors.text
+                    }
+
+                    onClicked: {
+                        if (selectionDialog.callback !== undefined) {
+                            selectionDialog.callback(index, modelData);
+                        }
+                        selectionDialog.closePage();
+                    }
+                }
+            }
+        }
+    }
+
+    PScrollDecorator { flickable: selectionDialogFlickable }
+}